> For the complete documentation index, see [llms.txt](https://docs.urbit.org/llms.txt). Markdown versions of documentation pages are available by appending `.md` to page URLs; this page is available as [Markdown](https://docs.urbit.org/hoon/stdlib/5a.md).

# 5a: Compiler Utilities

Internal compiler utilities and functions used by the Hoon compiler backend.

These functions are used internally by the compiler. They should not be used directly and are only listed here for completeness.

## `+musk` <a href="#musk" id="musk"></a>

Nock with block set.

#### Source

This function is extremely large, please refer to `hoon.hoon` for the source.

***

## `+bool` <a href="#bool" id="bool"></a>

Make loobean.

#### Source

```hoon
++  bool
  ^-  type
  (fork [%atom %f `%.y] [%atom %f `%.n] ~)
```

***

## `+cell` <a href="#cell" id="cell"></a>

Make `%cell` type.

#### Source

```hoon
++  cell
  ~/  %cell
  |=  [hed=type tal=type]
  ^-  type
  ?:(=(%void hed) %void ?:(=(%void tal) %void [%cell hed tal]))
```

***

## `+core` <a href="#core" id="core"></a>

Make `%core` type.

#### Source

```hoon
++  core
  ~/  %core
  |=  [pac=type con=coil]
  ^-  type
  ?:(=(%void pac) %void [%core pac con])
```

***

## `+hint` <a href="#hint" id="hint"></a>

Make `%hint` type.

#### Source

```hoon
++  hint
  |=  [p=(pair type note) q=type]
  ^-  type
  ?:  =(%void q)  %void
  ?:  =(%noun q)  %noun
  [%hint p q]
```

***

## `+face` <a href="#face" id="face"></a>

Make `%face` type.

#### Source

```hoon
++  face
  ~/  %face
  |=  [giz=$@(term tune) der=type]
  ^-  type
  ?:  =(%void der)
    %void
  [%face giz der]
```

***

## `+fork` <a href="#fork" id="fork"></a>

Make `%fork` type.

#### Source

```hoon
++  fork
  ~/  %fork
  |=  yed=(list type)
  =|  lez=(set type)
  |-  ^-  type
  ?~  yed
    ?~  lez  %void
    ?:  ?=([* ~ ~] lez)  n.lez
    [%fork lez]
  %=    $
      yed  t.yed
      lez
    ?:  =(%void i.yed)  lez
    ?:  ?=([%fork *] i.yed)  (~(uni in lez) p.i.yed)
    (~(put in lez) i.yed)
  ==
```

***

## `+cove` <a href="#cove" id="cove"></a>

Extract \[0 \*] axis.

#### Source

```hoon
++  cove
  |=  nug=nock
  ?-    nug
      [%0 *]   p.nug
      [%11 *]  $(nug q.nug)
      *        ~_(leaf+"cove" !!)
  ==
```

***

## `+comb` <a href="#comb" id="comb"></a>

Combine two formulas.

#### Source

```hoon
++  comb
  ~/  %comb
  |=  [mal=nock buz=nock]
  ^-  nock
  ?:  ?&(?=([%0 *] mal) !=(0 p.mal))
    ?:  ?&(?=([%0 *] buz) !=(0 p.buz))
      [%0 (peg p.mal p.buz)]
    ?:  ?=([%2 [%0 *] [%0 *]] buz)
      [%2 [%0 (peg p.mal p.p.buz)] [%0 (peg p.mal p.q.buz)]]
    [%7 mal buz]
  ?:  ?=([^ [%0 %1]] mal)
    [%8 p.mal buz]
  ?:  =([%0 %1] buz)
    mal
  [%7 mal buz]
```

***

## `+cond` <a href="#cond" id="cond"></a>

`?:` compile.

#### Source

```hoon
++  cond
  ~/  %cond
  |=  [pex=nock yom=nock woq=nock]
  ^-  nock
  ?:  =([%1 &] pex)  yom
  ?:  =([%1 |] pex)  woq
  ?:  =([%0 0] pex)  pex
  [%6 pex yom woq]
```

***

## `+cons` <a href="#cons" id="cons"></a>

Make formula cell.

#### Source

```hoon
++  cons
  ~/  %cons
  |=  [vur=nock sed=nock]
  ^-  nock
  ::  this optimization can remove crashes which are essential
  ::
  ::  ?:  ?=([[%0 *] [%0 *]] +<)
  ::  ?:  ?&(=(+(p.vur) p.sed) =((div p.vur 2) (div p.sed 2)))
  ::    [%0 (div p.vur 2)]
  ::  [vur sed]
  ?:  ?=([[%1 *] [%1 *]] +<)
    [%1 p.vur p.sed]
  [vur sed]
```

***

## `+fitz` <a href="#fitz" id="fitz"></a>

Aura compatibility.

#### Source

```hoon
++  fitz
  ~/  %fitz
  |=  [yaz=term wix=term]
  =+  ^=  fiz
      |=  mot=@ta  ^-  [p=@ q=@ta]
      =+  len=(met 3 mot)
      ?:  =(0 len)
        [0 %$]
      =+  tyl=(rsh [3 (dec len)] mot)
      ?:  &((gte tyl 'A') (lte tyl 'Z'))
        [(sub tyl 64) (end [3 (dec len)] mot)]
      [0 mot]
  =+  [yoz=(fiz yaz) wux=(fiz wix)]
  ?&  ?|  =(0 p.yoz)
          =(0 p.wux)
          &(!=(0 p.wux) (lte p.wux p.yoz))
      ==
      |-  ?|  =(%$ q.yoz)
              =(%$ q.wux)
              ?&  =((end 3 q.yoz) (end 3 q.wux))
                  $(q.yoz (rsh 3 q.yoz), q.wux (rsh 3 q.wux))
              ==
          ==
  ==
```

***

## `+flan` <a href="#flan" id="flan"></a>

Loobean `&`.

#### Source

```hoon
++  flan
  ~/  %flan
  |=  [bos=nock nif=nock]
  ^-  nock
  ?:  ?|  =(bos nif)
          =([%1 |] bos)
          =([%1 &] nif)
          =([%0 0] bos)
      ==
    bos
  ?:  ?|  =([%1 &] bos)
          =([%1 |] nif)
          =([%0 0] nif)
      ==
    nif
  [%6 bos nif [%1 |]]
```

***

## `+flip` <a href="#flip" id="flip"></a>

Loobean negation.

#### Source

```hoon
++  flip
  ~/  %flip
  |=  dyr=nock
  ?:  =([%0 0] dyr)  dyr
  [%6 dyr [%1 1] [%1 0]]
```

***

## `+flor` <a href="#flor" id="flor"></a>

Loobean `|`.

#### Source

```hoon
++  flor
  ~/  %flor
  |=  [bos=nock nif=nock]
  ^-  nock
  ?:  ?|  =(bos nif)
          =([%1 &] bos)
          =([%1 |] nif)
          =([%0 0] bos)
      ==
    bos
  ?:  ?|  =([%1 |] bos)
          =([%1 &] nif)
          =([%0 0] nif)
      ==
    nif
  [%6 bos [%1 &] nif]
```

***

## `+hike` <a href="#hike" id="hike"></a>

Compiler utility.

#### Source

```hoon
++  hike
  ~/  %hike
  |=  [a=axis pac=(list (pair axis nock))]
  |^  =/  rel=(map axis nock)  (roll pac insert)
      =/  ord=(list axis)      (sort ~(tap in ~(key by rel)) gth)
      |-  ^-  nock
      ?~  ord
        [%0 a]
      =/  b=axis  i.ord
      =/  c=nock  (~(got by rel) b)
      =/  d=nock  $(ord t.ord)
      [%10 [b c] d]
  ::
  ++  contains
    |=  [container=axis contained=axis]
    ^-  ?
    =/  big=@    (met 0 container)
    =/  small=@  (met 0 contained)
    ?:  (lte small big)  |
    =/  dif=@  (sub small big)
    =(container (rsh [0 dif] contained))
  ::
  ++  parent
    |=  a=axis
    `axis`(rsh 0 a)
  ::
  ++  sibling
    |=  a=axis
    ^-  axis
    ?~  (mod a 2)
      +(a)
    (dec a)
  ::
  ++  insert
    |=  [e=[axe=axis fol=nock] n=(map axis nock)]
    ^-  (map axis nock)
    ?:  =/  a=axis  axe.e
        |-  ^-  ?
        ?:  =(1 a)  |
        ?:  (~(has by n) a)
          &
        $(a (parent a))
      ::  parent already in
      n
    =.  n
      ::  remove children
      %+  roll  ~(tap by n)
      |=  [[axe=axis fol=nock] m=_n]
      ?.  (contains axe.e axe)  m
      (~(del by m) axe)
    =/  sib  (sibling axe.e)
    =/  un   (~(get by n) sib)
    ?~  un   (~(put by n) axe.e fol.e)
    ::  replace sibling with parent
    %=  $
      n  (~(del by n) sib)
      e  :-  (parent sib)
         ?:  (gth sib axe.e)
           (cons fol.e u.un)
         (cons u.un fol.e)
    ==
  --
```

***

## `+jock` <a href="#jock" id="jock"></a>

Compiler utility.

#### Source

```hoon
++  jock
  |=  rad=?
  |=  lot=coin  ^-  hoon
  ?-    -.lot
      ~
    ?:(rad [%rock p.lot] [%sand p.lot])
  ::
      %blob
    ?:  rad
      [%rock %$ p.lot]
    ?@(p.lot [%sand %$ p.lot] [$(p.lot -.p.lot) $(p.lot +.p.lot)])
  ::
      %many
    [%cltr (turn p.lot |=(a=coin ^$(lot a)))]
  ==
```

***

## `+look` <a href="#look" id="look"></a>

Compiler utility.

#### Source

```hoon
++  look
  ~/  %look
  |=  [cog=term dab=(map term hoon)]
  =+  axe=1
  |-  ^-  (unit [p=axis q=hoon])
  ?-  dab
      ~  ~
  ::
      [* ~ ~]
    ?:(=(cog p.n.dab) [~ axe q.n.dab] ~)
  ::
      [* ~ *]
    ?:  =(cog p.n.dab)
      [~ (peg axe 2) q.n.dab]
    ?:  (gor cog p.n.dab)
      ~
    $(axe (peg axe 3), dab r.dab)
  ::
      [* * ~]
    ?:  =(cog p.n.dab)
      [~ (peg axe 2) q.n.dab]
    ?:  (gor cog p.n.dab)
      $(axe (peg axe 3), dab l.dab)
    ~
  ::
      [* * *]
    ?:  =(cog p.n.dab)
      [~ (peg axe 2) q.n.dab]
    ?:  (gor cog p.n.dab)
      $(axe (peg axe 6), dab l.dab)
    $(axe (peg axe 7), dab r.dab)
  ==
```

***

## `+loot` <a href="#loot" id="loot"></a>

Compiler utility.

#### Source

```hoon
++  loot
  ~/  %loot
  |=  [cog=term dom=(map term tome)]
  =+  axe=1
  |-  ^-  (unit [p=axis q=hoon])
  ?-  dom
      ~  ~
      [* ~ ~]
    %+  bind  (look cog q.n.dom)
    |=((pair axis hoon) [(peg axe p) q])
      [* ~ *]
    =+  yep=(look cog q.n.dom)
    ?^  yep
      [~ (peg (peg axe 2) p.u.yep) q.u.yep]
    $(axe (peg axe 3), dom r.dom)
      [* * ~]
    =+  yep=(look cog q.n.dom)
    ?^  yep
      [~ (peg (peg axe 2) p.u.yep) q.u.yep]
    $(axe (peg axe 3), dom l.dom)
      [* * *]
    =+  yep=(look cog q.n.dom)
    ?^  yep
      [~ (peg (peg axe 2) p.u.yep) q.u.yep]
    =+  pey=$(axe (peg axe 6), dom l.dom)
    ?^  pey  pey
    $(axe (peg axe 7), dom r.dom)
  ==
```

***


---

# Agent Instructions
This documentation is published with GitBook. GitBook is the documentation platform designed so that both humans and AI agents can read, navigate, and reason over technical content effectively. Learn more at gitbook.com.

## Querying This Documentation
If you need additional information that is not directly available in this page, you can query the documentation by asking a question.

Perform an HTTP GET request on the following URL with the `ask` and `goal` query parameters:

```
GET https://docs.urbit.org/hoon/stdlib/5a.md?ask=<question>&goal=<user_goal>
```

`ask` is the immediate question: it should be specific, self-contained, and written in natural language.
`goal` is what the user is ultimately trying to achieve, the reason they need the answer. Sharing it helps GitBook give you a better, more relevant answer. A goal is most helpful when it describes the outcome the user wants rather than restating the question. For example, with `ask=how do I create an API token`, a goal like `automate deployments from our CI pipeline` lets GitBook tailor the answer to that use case.

The response will contain a direct answer to the question and relevant excerpts and sources from the documentation.

Use this mechanism when the answer is not explicitly present in the current page, you need clarification or additional context, or you want to retrieve related documentation sections.